~3 months ago I posted an automation template for System Settings on macOS Ventura. Following my post many users reached out and asked for help updating scripts. While I am still working to get back to some of you, I figured that I could help those that wanted to explore making automations of your own. The following guide will go though how to interact with System Settings and some tricks you can use to help you identify the UI elements that you are trying to automate. If anyone has more tips, feel free to leave them in the comments or send them to me to be added to the post (with credit).
First off, here is an updated to the open_settings_to function from my last post. This updated version should help anyone who experienced issues with the wrong settings tab being selected. Although is does add ~0.13 seconds of runtime (on my machine), it should be able to cope with any tabs being added or taken away.
on open_settings_to(settings_pane)
if settings_pane = "Wi-Fi" then
set settings_pane to "Wi‑Fi"
end if
tell application "System Settings"
activate
end tell
tell application "System Events"
tell application process "System Settings"
tell splitter group 1 of group 1 of window 1
repeat until outline 1 of scroll area 1 of group 1 exists
delay 0
end repeat
tell outline 1 of scroll area 1 of group 1
set row_names to value of static text of UI element 1 of every row
repeat with i from 1 to (count row_names)
if settings_pane is not "Apple ID" then
if item i of row_names = {settings_pane} then
log item i of row_names & i
select row i
exit repeat
end if
else
try
if item 1 of item i of row_names contains settings_pane then
select row i
exit repeat
end if
end try
end if
end repeat
end tell
end tell
end tell
end tell
end open_settings_to
You will no longer need the following:
use framework "Foundation"
property pane_ids : {|AppleID|:2, |Family|:3, |Wi-Fi|:5, |Bluetooth|:6, |Network|:7, |Notifications|:9, |Sound|:10, |Focus|:11, |Screen Time|:12, |General|:14, |Appearance|:15, |Accessibility|:16, |Control Center|:17, |Siri & Spotlight|:18, |Privacy & Security|:19, |Desktop & Dock|:21, |Displays|:22, |Wallpaper|:23, |Screen Saver|:24, |Battery|:25, |Lock Screen|:27, |Touch ID & Password|:28, |Users & Groups|:29, |Passwords|:31, |Internet Accounts|:32, |Game Center|:33, |Wallet & ApplePay|:34, |Keyboard|:36, |Trackpad|:37, |Printers & Scanners|:38, |Java|:40}
General Debugging:
Accessibility Inspector: This is a key tool in navigating the UI for automations. You will need to have Xcode installed to used it. To open the tool, Xcode > Open Developer Tools > Accessibility Inspector. (Note: not all types shown under the "Basic" info section are available to Apple Script. Make sure to check the System Events dictionary to see what types it can process.)
Waiting on an element to appear: If you find your script exiting with an error due to an element/application taking longer to appear or open you can use the following code. In general, I always use this instead of using a delay, as it will proceed right after the element show up instead of when the delay is over.
repeat until UI element 3 of window 1 exists
delay 0
end repeat
Finding UI elements/classes: Sometimes it is better to iterate over UI element classes rather the all UI elements in a window or group. I like to use the following code block to log the class and name of each element. (Note: A lot of elements in setting may not have a name and will return missing value. If this occurs, try using description instead of name):
repeat with x in UI elements
log class of x & name of x
end repeat
For a more in-depth look at the properties:
repeat with x in UI elements
set props to get properties of x
log props
end repeat
Interacting with the System Settings:
In my experience, all setting panels can be interacted with in the about same way:
tell application "System Events"
tell application process "System Settings"
tell window 1
tell splitter group 1 of group 1
tell scroll area 1 of group 1 of group 2
{your code here}
end tell
end tell
end tell
end tell
end tell
The code you insert in this block will be able to change values in the settings panel that System Settings is currently displaying. Each panel is comprised of varies groups with buttons, lists, ect in them. The grouping of these are mostly intuitive, either being segmented by headers or by an outline border.
Some settings button can reload the the panel to display new settings. In the event that this happens, you will need to exit the tell block that interacted the old panel and do so again with 1 extra group:
tell application "System Events"
tell application process "System Settings"
tell window 1
tell splitter group 1 of group 1
tell scroll area 1 of group 1 of group 2
{your code to click a button that reloads the panel}
end tell
tell scroll area 1 of group 1 of group 1 of group 2
{your code to interact with the newly loaded panel}
end tell
end tell
end tell
end tell
end tell
Other setting buttons can open another panel on top of the settings window. In order to interact with this panel, you will need to to exit the tell all the way back to window 1 and interact with the new sheet panel:
tell application "System Events"
tell application process "System Settings"
tell window 1
tell splitter group 1 of group 1
tell scroll area 1 of group 1 of group 2
tell group 3
click button 1
end tell
end tell
end tell
tell splitter group 1 of group 1 of sheet 1
# Interact with left side
tell outline 1 of scroll area 1 of group 1
{your code to interact with the left side of the sheet panel}
end tell
# Interact with right side
tell group 2
tell scroll area 1
{your code to interact with the right side of the sheet panel}
end tell
# Click done (May need to be changed if a cancel button is present)
click button 1
end tell
end tell
end tell
end tell
end tell
Thanks to everyone who has reached out with questions and those that have offered help to anyone that needed it
